options {
    LOOKAHEAD=21;
}

PARSER_BEGIN(GrailHierarchy)
public class GrailHierarchy {}
PARSER_END(GrailHierarchy)

SKIP : {
 	" "  |	"\r"  |	"\t"  | "\n"
}

/* COMMENTS */
MORE : {
    "\"" : IN_COMMENT 
}

<IN_COMMENT> 
MORE : {  /* for now skip everything in comment state */
    < ~["\""] >
}

<IN_COMMENT> 
SPECIAL_TOKEN : {
  <COMMENT: "\"" > : DEFAULT  /* Comment carried over from MORE clause */
}

<DEFAULT> TOKEN : {
    < NEWSUB: "newSub" >
  | < ADDSUB: "addSub" >
  | < ADDSUPER: "addSuper" >
  | < NEWATTRIBUTE: "newAttribute" >

  | < G: "grammatically">
  | < G_S: "grammaticallyAndSensibly">
  | < N: "necessarily">
  | < S: "sensibly">
  | < S_N: "sensiblyAndNecessarily">
  | < S_TN: "sensiblyAndTopicNecessarily">
  | < S_VN: "sensiblyAndValueNecessarily">
  | < TN: "topicNecessarily">
  | < WHICH: "which">
  | < WHICHG: "whichG">

  | < SPECIALISEDBY: "specialisedBy">
  | < REFINEDALONG: "refinedAlong">

  | < NAME: "name" >

  | < IGNORE: ( "rep" | "rename" | "model" | "gender" | "externalComment" | "author" ) >

  | < INT : (["0"-"9"])+ >
  | < ID:  <ALPHA> (<ALPHANUM>)* >
  /*| < ID:  (<ALPHANUM>)+ >*/
  | < ALPHA: (["a"-"z","A"-"Z"]) >
  | < ALPHANUM: (["a"-"z","A"-"Z","_","-","0"-"9"]) >
  | < LSQBRACKET: "[" >
  | < RSQBRACKET: "]" >
  | < LRBRACKET: "(" >
  | < RRBRACKET: ")" >
  | < LTBRACKET: "<" >
  | < GTBRACKET: ">" >
  | < SEMI: ";">
  | < COLON: ".">

  | < CAR: ( "allAll" | "manyMany" | "oneMany" | "manyOne" | "oneOne" ) >

}


void CompilationUnit(): {} {
  (grail())* <EOF>
}

void grail(): {} {
    grailSingle() ( grailRepeat() )* <COLON>
}
    void grailRepeat(): {} {
        <SEMI> operatorExpression()
    }
    void grailSingle(): {} {
        expression() operatorExpression()
    }
        void operatorExpression(): {} {
            simpleExpression() | parameterizedExpression() | attributeExpression()
        }
            void simpleExpression(): {} {
                simpleOperator() expression()
            }
            void parameterizedExpression(): {} {
                parameterizedOperator() property() expression()
            }
            void attributeExpression(): {} {
                attributeOperator() property() property() (cardinality())+
            }
                void cardinality(): {} {
                     <ID>   /* allAll is not necessary, so this will only use the last cardinality given */
                }

void expression(): {} {
    classSingle() | expressionList() | whichConjunction()
}
    void classSingle(): {} {
        <ID>
    }
    void expressionList(): {} {
        <LSQBRACKET> ( expression() )+ <RSQBRACKET>
    }
    void whichConjunction(): {} {
        <LRBRACKET> expression() whichOperator() angleBracketsOrPropertyExpression() <RRBRACKET>
    }
        void angleBracketsOrPropertyExpression(): {} {
            propertyExpression() | anglePairList()
        }
            void propertyExpression(): {} {
                property() expression()
            }
                void property(): {} {
                    <ID>
                }
            void anglePairList(): {} {
                <LTBRACKET> ( propertyExpression() )+ <GTBRACKET>
            }

void parameterizedOperator(): {} {
    <G> | <G_S> | <N> | <S> | <S_N> | <S_TN> | <S_VN>  | <TN>
}
void whichOperator(): {} {
    <WHICH> | <WHICHG>
}
void simpleOperator(): {} {
	<NEWSUB> | <ADDSUB> | <ADDSUPER> | <NAME> | <REFINEDALONG> | <SPECIALISEDBY>
}
void attributeOperator(): {} {
    <NEWATTRIBUTE>
}